12个Excel常用函数，工作效率翻3倍 「建议收藏」

01. MIN+IF 组合

功能：计算指定条件下的最小值

例：要计算人力部的最低分数。

G3 单元格公式：

=MIN(IF(A2:A9=F3,D2:D9))

说明：先用IF函数判断A列的部门是否等于F3指定的部门，如果条件成立，则返回D列对应的分数，否则返回逻辑值FALSE；

接下来再使用MIN函数计算出其中的最小值。MIN函数有一个特性，就是可以自动忽略逻辑值，所以只会对数值部分计算，最终得到指定部门的最低分数。

注：执行多项计算，在输入公式时要按 Shift+ctrl+Enter 键

02. IF+AND 组合

功能：并列多条件判断

例：在C列设置公式，如果A列值小于500且B列值为未到期，则返回"补款"，否则显示为空。

C4 单元格公式：

=IF(AND(A4<500,B2="否"),"补款","")

注：两个条件同时成立用 AND,任一个成立用 OR 函数。

03. INDEX+MATCH 组合

功能：根据条件查询

例：根据月份和费用项目，查找金额。

C10 单元格公式：

=INDEX(B2:G6,MATCH(B10,$A$2:$A$6,0),MATCH(A10,$B$1:$G$1,0))

说明：先用MATCH函数查找3月在第一行中的位置

=MATCH(B10,$A$2:$A$6,0)

再用MATCH函数查找费用项目在A列的位置

=MATCH(A10,$B$1:$G$1,0)

最后用INDEX根据行数和列数提取数值

=INDEX(区域,行数,列数）

04. VLOOKUP+MATCH 组合

功能：用于不确定列数的数据查询

例：根据B13单元格的姓名，在数据表中查询对应的项目。

C13 单元格公式：

=VLOOKUP(B13,A1:E9,MATCH(C12,1:1,),0)

05. IFERROR+VLOOKUP 组合

功能：当 VLOOKUP 查找不到时屏蔽查错误值

例：根据产品名称在上表中查找单价，如果产品不存在则显示为空白。

B9 单元格公式：

=IFERROR(VLOOKUP(A8,$A$1:$D$5,3,0),"")

06. TEXT+MID 组合

功能：用于日期字符串的提取和转换

例：根据B列身份证号码提取出生年月。

C3 单元格公式为：

=TEXT(MID(B2,7,8),"0-00-00")

说明：MID 函数用于从字符串的指定位置开始，提取特定数目的字符串。

MID(B2,7,8)就是从 B2 单元格的第 7 位开始，提取 8 位数字，结果为：19881109。

再使用 TEXT 函数，将这个字符串变成"0-00-00"的样式，结果为"1988-11-09"。

07. MID+FIND 组合

功能：根据条件截取字符串

例：在个人信里截取出年龄

B2 单元格公式：

=MID(A2,FIND(" ",A2)+1,9)

注：find 查找分隔符的位置，MID 负责截取字符

08. LEN+SUBSTITUTE 组合

功能：计算一个单元格内有几个项目

例：计算每个部门的人数。

C2 单元格公式：

=(LEN(B2)-LEN(SUBSTITUTE(B2,"、",))+1)*(B2<>"")

注：加上一个判断B2单元格是否为空格的判定，否则如果为空格就会返回错误的结果1

说明：先用LEN函数计算出 B 列单元格的字符长度，然后再用 SUBSTITUTE 函数将顿号全部替换掉之后，计算替换后的字符长度。

用字符长度减去替换后的字符长度，就是单元格内顿号的个数。

09. LEFT+LENB+LEN 组合

功能：分离汉字、数字和字母

例：

B5 单元格公式：

=LEFT(A2,LENB(A2)-LEN(A2))

注：带B的函数是按字节计数，而一个汉字占2个字节，数字和字母则占1个。所以用 LENB(A2)-LEN(A2) 可以倒推出汉字的个数，然后用 left 或 mid 函数截取。

10. SUMPRODUCT+COUNTIF 组合

功能：计算不重复值个数

例：统计B列的客户数量

D2 单元格公式：

=SUMPRODUCT(1/COUNTIF(B2:B19,B2:B19))

注：Countif 函数统计出每个客户的出现次数，Sumprodcut 对 1/出现次数进行求和。每个客户无论出现多少次，求和的结果都是1，求和后正好是不重复个数。

11. SUM+OFFSET+COUNT 组合

功能：最后N天求和

例：在D2单元格返回B列最近7天的销量

D2 单元格公式：

=SUM(OFFSET(B1,COUNTA(B:B)-7,0,7,1))

注：Counta 负责统计 B 列非空值个数，offset 负责生成动态最后 N 天区域，SUM 负责求和

12. INDEX+SMALL+ROW 组合

功能：一对多查找

例：在F列查找"张丽"的个人消费记录

F2 单元格公式：

{=INDEX(C:C,SMALL(IF(B$2:B$10=F$1,ROW($2:$10)),ROW(A1)))}

说明：

IF(B$2:B$10=F$1,ROW($2:$10))：如果B列的姓名和F1的姓名相同，就返回它的行号。不相同的返回FALSE

Row(a1)：是返回A1的行号1，如果向下复制会变为 Row(a2)，返回2，其实用它的目的是当公式向下复制时可以生成序号：1，2，3...然后取符合条件的第1个行号，第2个行号...

SMALL(): 从符合条件的行号中从小到大，逐个提取符合条件的行

INDEX() :根据取得的行号从C列提取值

{ }：数组公式（含有逐一运算的公式）需要按 ctrl+shift+enter 输入大括号（一定要是自动生成的，不能手输入大括号）。

End.

来源于网络

【零基础数据分析就业班】3月28日准时开课！

从提升技能、增加实战经验、面试辅导到成功入职

零基础入职数据分析、跨专业转行数据分析，你也可以！

扫描图中二维码，立刻咨询！